Panier d’achat

Aucun produit dans le panier.

L293D IC

13.00 د.م.

54 en stock

Quantité Discount (%) Prix
1 - 49 13.00 د.م.
50+ 23.08 % 10.00 د.م.

TUTORIAL: Control DC Motors with L293D IC Motor Driver Arduino


If you are planning on assembling your new robot friend, you will eventually want to learn about controlling DC motors. One of the easiest and inexpensive way to control DC motors is to interface L293D IC Motor Driver with Arduino. It can control both speed and spinning direction of two DC motors.

And as a bonus, it can even control a unipolar stepper motor like 28BYJ-48 or Bipolar stepper motor like NEMA 17.

One of the easiest and inexpensive way to control stepper motors is to interface L293D IC Motor Driver with Arduino. It can control both speed…

Controlling a DC Motor

In order to have a complete control over DC motor, we have to control its speed and rotation direction. This can be achieved by combining these two techniques.

  • PWM – For controlling speed
  • H-Bridge – For controlling rotation direction

PWM – For controlling speed

The speed of a DC motor can be controlled by varying its input voltage. A common technique for doing this is to use PWM (Pulse Width Modulation)

PWM is a technique where average value of the input voltage is adjusted by sending a series of ON-OFF pulses.

The average voltage is proportional to the width of the pulses known as Duty Cycle.

The higher the duty cycle, the greater the average voltage being applied to the dc motor(High Speed) and the lower the duty cycle, the less the average voltage being applied to the dc motor(Low Speed).

Below image illustrates PWM technique with various duty cycles and average voltages.

Pulse Width Modulation PWM Technique with Duty CyclesPulse Width Modulation(PWM) Technique

H-Bridge – For controlling rotation direction

The DC motor’s spinning direction can be controlled by changing polarity of its input voltage. A common technique for doing this is to use an H-Bridge.

An H-Bridge circuit contains four switches with the motor at the center forming an H-like arrangement.

Closing two particular switches at the same time reverses the polarity of the voltage applied to the motor. This causes change in spinning direction of the motor.

Below animation illustrates H-Bridge circuit working.

H-Bridge Working Motor Direction Control AnimationWorking of H-Bridge

L293D Motor Driver IC

L293D Dual H-Bridge Motor Driver IC Pinout

The L293D is a dual-channel H-Bridge motor driver capable of driving a pair of DC motors or one stepper motor.

That means it can individually drive up to two motors making it ideal for building two-wheel robot platforms.


Power Supply

The L293D IC motor driver actually has two power input pins viz. ‘Vcc1’ and ‘Vcc2’.

Vcc1 is used for driving the internal logic circuitry which should be 5V.

From Vcc2 pin the H-Bridge gets its power for driving the motors which can be 4.5V to 36V. And they both sink to a common ground named GND.


Output Terminals

The L293D IC motor driver’s output channels for the motor A and B are brought out to pins OUT1,OUT2 and OUT3,OUT4 respectively.

You can connect two DC motors having voltages between 4.5 to 36V to these terminals.

Each channel on the IC can deliver up to 600mA to the DC motor. However, the amount of current supplied to the motor depends on system’s power supply.

Control Pins

For each of the L293D’s channels, there are two types of control pins which allow us to control speed and spinning direction of the DC motors at the same time viz. Direction control pins & Speed control pins.

Direction Control Pins

Using the direction control pins, we can control whether the motor spins forward or backward. These pins actually control the switches of the H-Bridge circuit inside L293D IC.

The L293D IC has two direction control pins for each channel. The IN1,IN2 pins control the spinning direction of the motor A while IN3,IN4 control motor B.

The spinning direction of a motor can be controlled by applying either a logic HIGH(5 Volts) or logic LOW(Ground) to these pins. The below chart illustrates how this is done.

IN1 IN2 Spinning Direction
Low(0) Low(0) Motor OFF
High(1) Low(0) Forward
Low(0) High(1) Backward
High(1) High(1) Motor OFF

Speed Control Pins

The speed control pins viz. ENA and ENB are used to turn ON, OFF and control speed of motor A and motor B respectively.

Pulling these pins HIGH will make the motors spin, pulling it LOW will make them stop. But, with Pulse Width Modulation (PWM), we can actually control the speed of the motors.

Wiring L293D IC motor driver with Arduino UNO

Now that we know everything about the L293D IC, we can begin hooking it up to our Arduino!

Start by connecting power supply to the motors. In our experiment we are using DC Gearbox Motors(also known as ‘TT’ motors) that are usually found in two-wheel-drive robots. They are rated for 3 to 9V. So, we will connect external 9V power supply to the Vcc2 pin.

Next, we need to supply 5 Volts for the L293D’s logic circuitry. Connect Vcc1 pin to 5V output on Arduino. Make sure you common all the grounds in the circuit.

Now, the input and enable pins(ENA, IN1, IN2, IN3, IN4 and ENB) of the L293D IC are connected to six Arduino digital output pins(9, 8, 7, 5, 4 and 3). Note that the Arduino output pins 9 and 3 are both PWM-enabled.

Finally, connect one motor to across OUT1 & OUT2 and the other motor across OUT3 & OUT4. You can interchange your motor’s connections, technically, there is no right or wrong way.

When you’re done you should have something that looks similar to the illustration shown below.

Wiring L293D Motor Driver IC with DC Motors & ArduinoWiring L293D IC Motor Driver with DC Motors & Arduino


Arduino Code – Controlling a DC Motor

The following sketch will give you complete understanding on how to control speed and spinning direction of a DC motor with L293D IC motor driver and can serve as the basis for more practical experiments and projects. Plus d’information visite notre page Facebook.


// Motor A connections
int enA = 9;
int in1 = 8;
int in2 = 7;
// Motor B connections
int enB = 3;
int in3 = 5;
int in4 = 4;

void setup() {
 // Set all the motor control pins to outputs
 pinMode(enA, OUTPUT);
 pinMode(enB, OUTPUT);
 pinMode(in1, OUTPUT);
 pinMode(in2, OUTPUT);
 pinMode(in3, OUTPUT);
 pinMode(in4, OUTPUT);
 
 // Turn off motors - Initial state
 digitalWrite(in1, LOW);
 digitalWrite(in2, LOW);
 digitalWrite(in3, LOW);
 digitalWrite(in4, LOW);
}

void loop() {
 directionControl();
 delay(1000);
 speedControl();
 delay(1000);
}

// This function lets you control spinning direction of motors
void directionControl() {
 // Set motors to maximum speed
 // For PWM maximum possible values are 0 to 255
 analogWrite(enA, 255);
 analogWrite(enB, 255);

 // Turn on motor A & B
 digitalWrite(in1, HIGH);
 digitalWrite(in2, LOW);
 digitalWrite(in3, HIGH);
 digitalWrite(in4, LOW);
 delay(2000);
 
 // Now change motor directions
 digitalWrite(in1, LOW);
 digitalWrite(in2, HIGH);
 digitalWrite(in3, LOW);
 digitalWrite(in4, HIGH);
 delay(2000);
 
 // Turn off motors
 digitalWrite(in1, LOW);
 digitalWrite(in2, LOW);
 digitalWrite(in3, LOW);
 digitalWrite(in4, LOW);
}

// This function lets you control speed of the motors
void speedControl() {
 // Turn on motors
 digitalWrite(in1, LOW);
 digitalWrite(in2, HIGH);
 digitalWrite(in3, LOW);
 digitalWrite(in4, HIGH);
 
 // Accelerate from zero to maximum speed
 for (int i = 0; i < 256; i++) {
  analogWrite(enA, i);
  analogWrite(enB, i);
  delay(20);
 }
 
 // Decelerate from maximum speed to zero
 for (int i = 255; i >= 0; --i) {
  analogWrite(enA, i);
  analogWrite(enB, i);
  delay(20);
 }
 
 // Now turn off motors
 digitalWrite(in1, LOW);
 digitalWrite(in2, LOW);
 digitalWrite(in3, LOW);
 digitalWrite(in4, LOW);
}

Code Explanation:

The arduino code is pretty straightforward. It doesn’t require any libraries to get it working. The sketch starts with declaring Arduino pins to which L293D’s control pins are connected.

// Motor A connections
int enA = 9;
int in1 = 8;
int in2 = 7;
// Motor B connections
int enB = 3;
int in3 = 5;
int in4 = 4;

In setup section of code, all the motor control pins are declared as digital OUTPUT and pulled LOW to turn both the motors OFF.

void setup() {
 // Set all the motor control pins to outputs
 pinMode(enA, OUTPUT);
 pinMode(enB, OUTPUT);
 pinMode(in1, OUTPUT);
 pinMode(in2, OUTPUT);
 pinMode(in3, OUTPUT);
 pinMode(in4, OUTPUT);
 
 // Turn off motors - Initial state
 digitalWrite(in1, LOW);
 digitalWrite(in2, LOW);
 digitalWrite(in3, LOW);
 digitalWrite(in4, LOW);
}

In loop section of the code we call two user defined functions at an interval of a second.

void loop() {
 directionControl();
 delay(1000);
 speedControl();
 delay(1000);
}

These functions are:

  • directionControl() – This function spins both motors forward at maximum speed for two seconds. It then reverses the motor’s spinning direction and spins for another two seconds. Finally it turns the motors off.
    void directionControl() {
     // Set motors to maximum speed
     // For PWM maximum possible values are 0 to 255
     analogWrite(enA, 255);
     analogWrite(enB, 255);
    
     // Turn on motor A & B
     digitalWrite(in1, HIGH);
     digitalWrite(in2, LOW);
     digitalWrite(in3, HIGH);
     digitalWrite(in4, LOW);
     delay(2000);
     
     // Now change motor directions
     digitalWrite(in1, LOW);
     digitalWrite(in2, HIGH);
     digitalWrite(in3, LOW);
     digitalWrite(in4, HIGH);
     delay(2000);
     
     // Turn off motors
     digitalWrite(in1, LOW);
     digitalWrite(in2, LOW);
     digitalWrite(in3, LOW);
     digitalWrite(in4, LOW);
    }

speedControl() – This function accelerates both the motors from zero to maximum speed by producing PWM signals using analogWrite() function, then it decelerates them back to zero. Finally it turns the motors off.

void speedControl() {
 // Turn on motors
 digitalWrite(in1, LOW);
 digitalWrite(in2, HIGH);
 digitalWrite(in3, LOW);
 digitalWrite(in4, HIGH);
 
 // Accelerate from zero to maximum speed
 for (int i = 0; i < 256; i++) {
  analogWrite(enA, i);
  analogWrite(enB, i);
  delay(20);
 }
 
 // Decelerate from maximum speed to zero
 for (int i = 255; i >= 0; --i) {
  analogWrite(enA, i);
  analogWrite(enB, i);
  delay(20);
 }
 
 // Now turn off motors
 digitalWrite(in1, LOW);
 digitalWrite(in2, LOW);
 digitalWrite(in3, LOW);
 digitalWrite(in4, LOW);
}

Plus d’information visite notre page Facebook.


 

Avis

Il n’y a pas encore d’avis.

Soyez le premier à laisser votre avis sur “L293D IC”

Votre adresse e-mail ne sera pas publiée. Les champs obligatoires sont indiqués avec *

Tous les résultats de recherche
×